
<MvCOMMENT>
|
| Miva Merchant v4.x
|
| This file and the source codes contained herein are the property
| of Miva Corporation.  Use of this file is restricted to the specific
| terms and conditions in the License Agreement associated with this
| file.  Distribution of this file or portions of this file for uses
| not covered by the License Agreement is not allowed without a written
| agreement signed by an officer of Miva Corporation.
|
| Copyright 1998-2001 Miva Corporation.  All rights reserved.
| http://www.miva.com/
|
| $Source: /home/cvs/merchant/Merchant/features/sta/sta.mv,v $
|
| Prefix         : MER-MER-
| Next Error Code: 7    
| Next Text ID   : 23   
|
</MvCOMMENT>

<MvCOMMENT>
|
| Stats Add
|
</MvCOMMENT>

<MvFUNCTION NAME = "Stats_Add_Hits" STANDARDOUTPUTLEVEL = "text, html, compresswhitespace">
<MvASSIGN NAME = "l.ok" VALUE = "1">	
	
<MvDO FILE = "{ g.Module_Feature_STA_DB }" NAME = "l.ok" VALUE = "{ _DB_Store_Open_Stats( Stores.d.id ) }">
<MvIF EXPR = "{ l.ok }">
	<MvASSIGN NAME = "Stats.d.hits" VALUE = "{ Stats.d.hits + 1 }">
	<MvUPDATE NAME = "Stats">
</MvIF>

<MvFUNCTIONRETURN VALUE = "{ l.ok }">
</MvFUNCTION>

<MvFUNCTION NAME = "Stats_Add_Visits" STANDARDOUTPUTLEVEL = "text, html, compresswhitespace">
<MvASSIGN NAME = "l.ok" VALUE = "1">	

<MvDO FILE = "{ g.Module_Feature_STA_DB }" NAME = "l.ok" VALUE = "{ _DB_Store_Open_Stats( Stores.d.id ) }">
<MvIF EXPR = "{ l.ok }">
	<MvASSIGN NAME = "Stats.d.visits" VALUE = "{ Stats.d.visits + 1 }">
	<MvUPDATE NAME = "Stats">
</MvIF>

<MvFUNCTIONRETURN VALUE = "{ l.ok }">
</MvFUNCTION>

<MvFUNCTION NAME = "Stats_Add_Orders" STANDARDOUTPUTLEVEL = "text, html, compresswhitespace">
<MvASSIGN NAME = "l.ok" VALUE = "1">	

<MvDO FILE = "{ g.Module_Feature_STA_DB }" NAME = "l.ok" VALUE = "{ _DB_Store_Open_Stats( Stores.d.id ) }">
<MvIF EXPR = "{ l.ok }">
	<MvASSIGN NAME = "Stats.d.orders" VALUE = "{ Stats.d.orders + 1 }">
	<MvUPDATE NAME = "Stats">
</MvIF>

<MvFUNCTIONRETURN VALUE = "{ l.ok }">
</MvFUNCTION>

<MvFUNCTION NAME = "Stats_Add_Revenue" PARAMETERS = "tot" STANDARDOUTPUTLEVEL = "text, html, compresswhitespace">
<MvASSIGN NAME = "l.ok" VALUE = "1">	

<MvDO FILE = "{ g.Module_Feature_STA_DB }" NAME = "l.ok" VALUE = "{ _DB_Store_Open_Stats( Stores.d.id ) }">
<MvIF EXPR = "{ l.ok }">
	<MvASSIGN NAME = "Stats.d.revenue" VALUE = "{ Stats.d.revenue + l.tot }">
	<MvUPDATE NAME = "Stats">
</MvIF>

<MvFUNCTIONRETURN VALUE = "{ l.ok }">
</MvFUNCTION>

<MvFUNCTION NAME = "Stats_Add_Products" PARAMETERS = "qty" STANDARDOUTPUTLEVEL = "text, html, compresswhitespace">
<MvASSIGN NAME = "l.ok" VALUE = "1">	

<MvDO FILE = "{ g.Module_Feature_STA_DB }" NAME = "l.ok" VALUE = "{ _DB_Store_Open_Stats( Stores.d.id ) }">
<MvIF EXPR = "{ l.ok }">
	<MvASSIGN NAME = "Stats.d.products" VALUE = "{ Stats.d.products + l.qty }">
	<MvUPDATE NAME = "Stats">
</MvIF>

<MvFUNCTIONRETURN VALUE = "{ l.ok }">
</MvFUNCTION>

<MvFUNCTION NAME = "ProdStats_Add_Counts" PARAMETERS = "product_id, count" STANDARDOUTPUTLEVEL = "text, html, compresswhitespace">
<MvASSIGN NAME = "l.ok" VALUE = "1">	

<MvDO FILE = "{ g.Module_Feature_STA_DB }" NAME = "l.ok" VALUE = "{ _DB_Store_Open_ProdStats( Stores.d.id ) }">
<MvIF EXPR = "{ l.ok }">
	<MvPRIMARY NAME = "ProdStats" INDEX = "{ g._DB_Store_Directory $ 'prdsta_p.mvx' }">
	<MvFIND NAME = "ProdStats" VALUE = "{ l.product_id }" EXACT>
	<MvIF EXPR = "{ NOT ProdStats.d.EOF }">
		<MvASSIGN NAME = "ProdStats.d.count" VALUE = "{ ProdStats.d.count + l.count }">
		<MvUPDATE NAME = "ProdStats">
	<MvELSE>
		<MvASSIGN NAME = "ProdStats.d.product_id" 		VALUE = "{ l.product_id }">
		<MvASSIGN NAME = "ProdStats.d.count" 	VALUE = "{ l.count }">
		<MvADD NAME = "ProdStats">
	</MvIF>
</MvIF>

<MvFUNCTIONRETURN VALUE = "{ l.ok }">
</MvFUNCTION>

<MvFUNCTION NAME = "Sta_Display_Statistics" PARAMETERS = "store_id" STANDARDOUTPUTLEVEL = "text, html, compresswhitespace">
	<MvASSIGN NAME = "l.ok" VALUE = "1">	

	<MvDO FILE = "{ g.Module_Feature_STA_DB }" NAME = "l.ok" VALUE = "{ _DB_Store_Open_Stats( l.store_id ) }">
	<MvIF EXPR = "{ l.ok }">
		<TABLE BORDER = 0 CELLPADDING = 5 CELLSPACING = 0 WIDTH = "100%">
			<TR><TD BGCOLOR = "#cccccc" COLSPAN = 2>
				<FONT FACE = "Arial, Helvetica" SIZE = "-1" COLOR = "#000000"><B>
				<MvLOCALIZED ID = "MER-MER-00010">
					<MvLOCALIZED-TEXT LANGUAGE = "en-US">Statistics</MvLOCALIZED-TEXT>
				</MvLOCALIZED>
				</B></FONT>
			</TD>
			<MvDO FILE = "{ g.Module_Feature_STA_DB }" NAME = "l.ok" VALUE = "{ _DB_Store_Open_ProdStats( l.store_id ) }">
			<MvIF EXPR = "{ l.ok }">
				<MvDO FILE = "{ g.Module_Admin }" NAME = "l.can_resetstats" VALUE = "{ CanI( 'RSTA', 0, 0, 1, 0 ) }">

				<MvIF EXPR = "{ l.can_resetstats }">
					<TD ALIGN = "right" BGCOLOR = "#cccccc" NOWRAP>
						<FONT FACE = "Arial, Helvetica" SIZE = "-1">   
							<MvLOCALIZED NAME = "l.reset_text" ID = "MER-MER-00021">
								<MvLOCALIZED-TEXT LANGUAGE = "en-US">Reset Statistics</MvLOCALIZED-TEXT>
							</MvLOCALIZED>
							<A HREF = "{ 'JavaScript:PopupStatReset( \'' $ encodeentities( Stores.d.code ) $ '\' );' }"><MvEVAL EXPR = "{ l.reset_text }"></A><BR>
							<MvLOCALIZED ID = "MER-MER-00011">
								<MvLOCALIZED-TOKEN NAME = "month" VALUE = "{ Stats.d.resetdate_month }">
								<MvLOCALIZED-TOKEN NAME = "day" VALUE = "{ Stats.d.resetdate_day }">
								<MvLOCALIZED-TOKEN NAME = "year" VALUE = "{ Stats.d.resetdate_year }">						
								<MvLOCALIZED-TEXT LANGUAGE = "en-US">Last Reset on: %month%/%day%/%year%</MvLOCALIZED-TEXT>
							</MvLOCALIZED>
						</FONT>
					</TD>
				</MvIF>
			</MvIF>
			</TR>

			<TR><TD BGCOLOR = "#ffffff">
				<FONT FACE = "Arial, Helvetica" SIZE = "-1">
					<MvLOCALIZED ID = "MER-MER-00012">
						<MvLOCALIZED-TEXT LANGUAGE = "en-US">Hits:</MvLOCALIZED-TEXT>
					</MvLOCALIZED>
				</FONT>
			</TD><TD BGCOLOR = "#ffffff" WIDTH = "100%">
				<FONT FACE = "Arial, Helvetica" SIZE = "-1">
					<MvEVAL EXPR = "{ Stats.d.hits }">
				</FONT>
			</TD></TR>

			<TR><TD BGCOLOR = "#ffffff">
				<FONT FACE = "Arial, Helvetica" SIZE = "-1">
					<MvLOCALIZED ID = "MER-MER-00013">
						<MvLOCALIZED-TEXT LANGUAGE = "en-US">Visits:</MvLOCALIZED-TEXT>
					</MvLOCALIZED>
				</FONT>
			</TD><TD BGCOLOR = "#ffffff">
				<FONT FACE = "Arial, Helvetica" SIZE = "-1">
					<MvEVAL EXPR = "{ Stats.d.visits }"> 
				</FONT>
			</TD></TR>

			<TR><TD BGCOLOR = "#ffffff">
				<FONT FACE = "Arial, Helvetica" SIZE = "-1">
					<MvLOCALIZED ID = "MER-MER-00014">
						<MvLOCALIZED-TEXT LANGUAGE = "en-US">Orders:</MvLOCALIZED-TEXT>
					</MvLOCALIZED>
				</FONT>
			</TD><TD BGCOLOR = "#ffffff">
				<FONT FACE = "Arial, Helvetica" SIZE = "-1">
					<MvEVAL EXPR = "{ Stats.d.orders }">
				</FONT>
			</TD></TR>

			<TR><TD BGCOLOR = "#ffffff">
				<FONT FACE = "Arial, Helvetica" SIZE = "-1">
					<MvLOCALIZED ID = "MER-MER-00015">
						<MvLOCALIZED-TEXT LANGUAGE = "en-US">Revenue:</MvLOCALIZED-TEXT>
					</MvLOCALIZED>
				</FONT>
			</TD><TD BGCOLOR = "#ffffff">
				<FONT FACE = "Arial, Helvetica" SIZE = "-1">
					<MvEVAL EXPR = "{ Stats.d.revenue }">
				</FONT>
			</TD></TR>

			<TR><TD BGCOLOR = "#ffffff" NOWRAP>
				<FONT FACE = "Arial, Helvetica" SIZE = "-1">
					<MvLOCALIZED ID = "MER-MER-00016">
						<MvLOCALIZED-TEXT LANGUAGE = "en-US">Products Sold:</MvLOCALIZED-TEXT>
					</MvLOCALIZED>
				</FONT>
			</TD><TD BGCOLOR = "#ffffff">
				<FONT FACE = "Arial, Helvetica" SIZE = "-1">
					<MvEVAL EXPR = "{ Stats.d.products }">
				</FONT>
			</TD></TR>
		</TABLE>
	</MvIF>

	<MvFUNCTIONRETURN VALUE = "{ l.ok }">
</MvFUNCTION>

<MvFUNCTION NAME = "Sta_Display_BestSellers" PARAMETERS = "store_id" STANDARDOUTPUTLEVEL = "text, html, compresswhitespace">
	<MvASSIGN NAME = "l.ok" VALUE = "1">	
	<MvASSIGN NAME = "l.n" VALUE = 0>
	
	<MvDO FILE = "{ g.Module_Feature_STA_DB }" NAME = "l.ok" VALUE = "{ _DB_Store_Open_ProdStats( l.store_id ) }">
	<MvIF EXPR = "{ l.ok }">
		<MvSETINDEX NAME = "ProdStats" INDEXES = "{ g._DB_Store_Directory $ 'prdsta_c.mvx' }">
		<MvDO FILE = "{ g.Module_Library_DB }" NAME = "l.ok" VALUE = "{ _DB_Store_Open_Products() }">
		<MvASSIGN NAME = "l.top_five" VALUE = "1">
		
		<TABLE BORDER = 0 CELLPADDING = 1 CELLSPACING = 0 WIDTH = "100%">
			<TR><TD>
				&nbsp;
			</TD></TR>

			<TR><TD BGCOLOR = "#ffffff">
				<TABLE BORDER = "0" CELLPADDING = "5" CELLSPACING = "0" WIDTH = "100%">
				<TR><TD BGCOLOR = "#cccccc" NOWRAP>
					<FONT FACE = "Arial, Helvetica" SIZE = "-1"><B>
					<MvLOCALIZED ID = "MER-MER-00017">
						<MvLOCALIZED-TEXT LANGUAGE = "en-US">Best Sellers</MvLOCALIZED-TEXT>
					</MvLOCALIZED></B>
					</FONT>
				</TD><TD BGCOLOR = "#cccccc" NOWRAP>
					&nbsp;
				</TD></TR>
				
				<MvASSIGN NAME = "l.shown" VALUE = 0>
				<MvWHILE EXPR = "{ ( l.top_five LE 5 ) AND ( NOT ProdStats.d.EOF ) }">
					<MvIF EXPR = "{ ProdStats.d.product_id NE 0 }">
						<MvASSIGN NAME = "l.shown" VALUE = "{ l.shown + 1 }">

						<MvFIND NAME = "Products" VALUE = "{ ProdStats.d.product_id }" EXACT>
						<MvIF EXPR = "{ NOT( Products.d.EOF ) }">
							<MvIF EXPR = "{ ProdStats.d.prod_name NE Products.d.name }">
								<MvASSIGN NAME = "ProdStats.d.prod_name" VALUE = "{ Products.d.name }">
								<MvUPDATE NAME = "ProdStats">
							</MvIF>
						</MvIF>

						<TR><TD BGCOLOR = "#ffffff">
							<FONT FACE = "Arial, Helvetica" SIZE = "-1">
								<MvEVAL EXPR = "{ ProdStats.d.prod_name }">:
							</FONT>
						</TD><TD BGCOLOR = "#ffffff">
							<FONT FACE = "Arial, Helvetica" SIZE = "-1">
								<MvEVAL EXPR = "{ ProdStats.d.count }">
							</FONT>
						</TD></TR>

						<MvASSIGN NAME = "l.top_five" VALUE = "{ l.top_five + 1 }">
					</MvIF>
				
					<MvSKIP NAME = "Prodstats" ROWS = "1">
				</MvWHILE>

				<MvIF EXPR = "{ NOT l.shown }">
					<TR><TD BGCOLOR = "#ffffff">
						<FONT FACE = "Arial, Helvetica" SIZE = "-1"><I>
						<MvLOCALIZED ID = "MER-MER-00019">
							<MvLOCALIZED-TEXT LANGUAGE = "en-US">No Best Sellers Currently Available</MvLOCALIZED-TEXT>
						</MvLOCALIZED>
						</I></FONT>
					</TD></TR>
				</MvIF>

				<TR><TD>
					&nbsp;
				</TD></TR>

				</TABLE>
			</TD></TR>
		</TABLE>
	</MvIF>

	<MvFUNCTIONRETURN VALUE = "{ l.ok }">
</MvFUNCTION>
	
<MvFUNCTION NAME = "Action_Store_ResetStats">
	<MvASSIGN NAME = "l.ok" VALUE = 1>
	<MvDO FILE = "{ g.Module_Admin }" NAME = "l.can_resetstats" VALUE = "{ CanI( 'RSTA', 0, 0, 1, 0 ) }">

	<MvIF EXPR = "{ l.can_resetstats }">
		<MvDO FILE = "{ g.Module_Feature_STA_DB }" NAME = "l.ok" VALUE = "{ STA_Store_Create( Stores.d.id ) }">
	</MvIF>

	<SCRIPT LANGUAGE = "JavaScript">
<!--
		opener.location.reload();

		window.close();
//-->
	</SCRIPT>
	
	<MvFUNCTIONRETURN VALUE = "{ l.ok }">
</MvFUNCTION>	

<MvFUNCTION NAME = "Screen_ResetStats" STANDARDOUTPUTLEVEL = "text, html, compresswhitespace">
	<MvASSIGN NAME = "l.ok" VALUE = 1>
	<TITLE>
		<MvLOCALIZED ID = "MER-ADM-00833">
			<MvLOCALIZED-TOKEN NAME = "store_name" VALUE = "{ encodeentities( Stores.d.name ) }">
			<MvLOCALIZED-TEXT LANGUAGE = "en-US">Reset Statistics for Store %store_name%?</MvLOCALIZED-TEXT>
		</MvLOCALIZED>
	</TITLE>
	<BODY BGCOLOR = "#ffffff" BACKGROUND = "{ 'graphics/' $ s.miva_language $ '/wizards/blade_bg.gif' }">
	<SCRIPT LANGUAGE = "JavaScript">
<!--
function Close_ResetStats()
{
	window.close();
}
//-->
	</SCRIPT>

	<MvIF EXPR = "{ l.ok }">
		<TABLE BORDER = 0 CELLPADDING = 5 CELLSPACING = 0 WIDTH = "100%">
		<TR><TD ALIGN = "left">
			<FONT FACE = "Arial, Helvetica" SIZE = "-1">
			<MvLOCALIZED ID = "MER-ADM-00833">
				<MvLOCALIZED-TOKEN NAME = "store_name" VALUE = "{ encodeentities( Stores.d.name ) }">
				<MvLOCALIZED-TEXT LANGUAGE = "en-US">Reset Statistics for Store <B>%store_name%</B>?</MvLOCALIZED-TEXT>
			</MvLOCALIZED>
			</FONT>
		</TD></TR>

		<TR><TD ALIGN = "left">
			<FONT FACE = "Arial, Helvetica" SIZE = "-1">
			<MvLOCALIZED ID = "MER-ADM-00222">
				<MvLOCALIZED-TOKEN NAME = "store_name" VALUE = "{ encodeentities( Stores.d.name ) }">
				<MvLOCALIZED-TEXT LANGUAGE = "en-US">This will reset the statistics for this store; all the statistics from last reset will be lost.</MvLOCALIZED-TEXT>
			</MvLOCALIZED>
			</FONT>
		</TD></TR>
		</TABLE>


		<TABLE BORDER = 0 CELLPADDING = 5 CELLSPACING = 0 WIDTH = "100%">
			<TR><TD COLSPAN = 2>
				&nbsp;
			</TD></TR>

			<TR><TD ALIGN = "left" VALIGN = "top">
				<FONT FACE = "Arial, Helvetica" SIZE = "-1">
				<MvEVAL EXPR = "{ StoreNotes.d.note }">
				</FONT>
			</TD></TR>

			<TR><TD>
				&nbsp;
			</TD></TR>

			<TR><TD VALIGN = "bottom" ALIGN = "left">
				<FONT FACE = "Arial, Helvetica" SIZE = "-1">
					<FORM ACTION = "{ g.sessionurl }" METHOD = "POST">
						<INPUT TYPE = "hidden" NAME = "Action" VALUE = "RSTA">
						<INPUT TYPE = "hidden" NAME = "Screen" VALUE = "RSTA">
						<INPUT TYPE = "hidden" NAME = "Note_ID" VALUE = "{ encodeentities( g.Note_ID ) }">
						<INPUT TYPE = "hidden" NAME = "Store_Code" VALUE = "{ encodeentities( g.Store_Code ) }">
						<MvLOCALIZED ID = "MER-MER-00022">
							<MvLOCALIZED-TEXT LANGUAGE = "en-US"><INPUT TYPE = "submit" NAME = "RSTA" VALUE = "Reset"></MvLOCALIZED-TEXT>
						</MvLOCALIZED>
					</FORM>
				</FONT>
			</TD><TD VALIGN = "bottom" ALIGN = "right">
				<FONT FACE = "Arial, Helvetica" SIZE = "-1">
				<MvLOCALIZED ID = "MER-NOT-00003">
					<MvLOCALIZED-TEXT LANGUAGE = "en-US">
						<FORM>
							<INPUT TYPE = "button" VALUE = "Close" ONCLICK = "Close_ResetStats();">
						</FORM>
					</MvLOCALIZED-TEXT>
				</MvLOCALIZED>
				</FONT>
			</TD></TR>
		</TABLE>
	</MvIF>

	</BODY>
	<MvFUNCTIONRETURN VALUE = "{ l.ok }">
</MvFUNCTION>

<MvFUNCTION NAME = "Screen_Deleted_Note" STANDARDOUTPUTLEVEL = "text, html, compresswhitespace">
	<MvFUNCTIONRETURN VALUE = 1>
</MvFUNCTION>

<MvFUNCTION NAME = "STA_Upgrade_Setup_State" STANDARDOUTPUTLEVEL = "">
	<MvCOMMENT>
	|
	| stats.dbf
	| *********************************************************************************************
	|
	| 4.00: Created
	|
	</MvCOMMENT>

	<MvDO FILE = "{ g.Module_Upgrade }" NAME = "l.null" VALUE = "{ Store_DB_New_Insert( 4.00, 'stats.dbf',
					   'hits		NUMBER,
						visits		NUMBER,
						orders		NUMBER,
						revenue 	NUMBER ( 10.2 ),
						products	NUMBER,
						resetdate	DATE' ) }">

	<MvCOMMENT>
	|
	| prdsta.dbf
	| *********************************************************************************************
	|
	| 4.00: Created
	|
	</MvCOMMENT>

	<MvDO FILE = "{ g.Module_Upgrade }" NAME = "l.null" VALUE = "{ Store_DB_New_Insert( 4.00, 'prdsta.dbf',
							'product_id	NUMBER,
							 count		NUMBER' ) }">
	<MvDO FILE = "{ g.Module_Upgrade }" NAME = "l.null" VALUE = "{ Store_DB_Change_Insert( 4.10, 'prdsta.dbf',
							'product_id	NUMBER,
							 count		NUMBER,
							 prod_name	CHAR( 100 )' ) }">

	<MvDO FILE = "{ g.Module_Upgrade }" NAME = "l.null" VALUE = "{ Store_DB_Index_Insert( 4.00, 'ProdStats', 'prdsta.dbf', 'prdsta_p.mvx', 'ProdStats.d.product_id', 'nounique, ascending' ) }">
	<MvDO FILE = "{ g.Module_Upgrade }" NAME = "l.null" VALUE = "{ Store_DB_Index_Insert( 4.00, 'ProdStats', 'prdsta.dbf', 'prdsta_c.mvx', 'ProdStats.d.count', 'nounique, descending' ) }">
</MvFUNCTION>

<MvFUNCTION NAME = "STA_Upgrade_Store_DB_New_Stats" STANDARDOUTPUTLEVEL = "">
	<MvASSIGN NAME = "Temporary.d.hits" 	VALUE = "0">
	<MvASSIGN NAME = "Temporary.d.visits" 	VALUE = "0">
	<MvASSIGN NAME = "Temporary.d.orders" 	VALUE = "0">
	<MvASSIGN NAME = "Temporary.d.revenue" 	VALUE = "0.00">
	<MvASSIGN NAME = "Temporary.d.products" VALUE = "0">
	<MvASSIGN NAME = "Temporary.d.resetdate" VALUE = "{s.dyn_time_t}">

	<MvADD NAME = "Temporary">
	<MvFUNCTIONRETURN VALUE = 1>
</MvFUNCTION>

<MvFUNCTION NAME = "STA_Upgrade_Store_DB_ProdStats" STANDARDOUTPUTLEVEL = "">
	<MvASSIGN NAME = "Temporary.d.product_id" 	VALUE = "{ Original.d.product_id }">
	<MvASSIGN NAME = "Temporary.d.count" 	VALUE = "{ Original.d.count }">
	<MvIF EXPR = "{ g.Upgrade_Version_From LT 4.10 }">
		<MvASSIGN NAME = "Temporary.d.prod_name" 	VALUE = "{ Original.d.prod_name }">
	<MvELSE>
		<MvASSIGN NAME = "Temporary.d.prod_name" 	VALUE = "Product Deleted">
	</MvIF>

	<MvADD NAME = "Temporary">
	<MvFUNCTIONRETURN VALUE = 1>
</MvFUNCTION>

<MvFUNCTION NAME = "STA_Upgrade_Store_DB_New_InventoryProductSettings">
	<MvFUNCTIONRETURN VALUE = "1">
</MvFUNCTION>

<MvFUNCTION NAME = "STA_Upgrade_Store_DB_New_InventoryProductCounts">
	<MvFUNCTIONRETURN VALUE = "1">
</MvFUNCTION>


